Wikidata:WikiProject Norway

Project for coordination regarding properties and items relating to Norway.

Important properties that are missing labels in Norsk, bokmål (nb)

At the time of writing this, there is about 6600 properties of about 10000 that do not have a Norwegian translation. Of these around 900 are "important", so if you are bored, please consider doing a quality translation of any one of these.

SELECT ?item ?itemLabel
WHERE {
  ?item rdf:type wikibase:Property.
  FILTER NOT EXISTS { ?item wikibase:propertyType wikibase:ExternalId. }
  FILTER NOT EXISTS { ?item rdfs:label ?nblabel. FILTER(LANG(?nblabel) = "nb") }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Sider på norsk Wikipedia som mangler instance of (P31) eller subclass of (P279) på Wikidata

En del av disse kan være duplikater og kan flettes, andre kan få tilføyd P31 utsagn.

SELECT ?item ?name ?article
WHERE {
  ?article schema:about ?item ;
    schema:name ?name ;
    schema:isPartOf <https://no.wikipedia.org/> .
  # ?item wikibase:sitelinks 1 .
  FILTER NOT EXISTS { ?item wdt:P31|wdt:P279 [] . }
}
#LIMIT 1000

Try it!

Artikler på norsk wikipedia, uten bilde på Wikidata men med kobling til kategori på Commons

select ?item ?itemLabel ?instLabel ?sl_nowiki ?sl_commons
where {
  {
    select *
    where {
      ?item wdt:P17|wdt:P27|wdt:P495|wdt:P1532|wdt:P8047 wd:Q20 .
      ?item wdt:P31 ?inst .
      filter not exists { ?item wdt:P18 [] . }
      ?sl_nowiki schema:about ?item ;
        schema:isPartOf <https://no.wikipedia.org/> .
      ?sl_commons schema:about ?item ;
        schema:isPartOf <https://commons.wikimedia.org/> .
    }
  }
  service wikibase:label { bd:serviceParam wikibase:language "nb,nn,en" . }
}

Try it!

Items

• Norway (Q20)
• Norwegian (Q9043)
• helsenorge.no (Q19374100)
• Act relating to the admission of foreign nationals into the realm and their stay here (Q12008659)
• Regulations on patient records of Norway (Q91262441)
• Regulations on the Entry of Foreign Nationals Into the Kingdom of Norway and Their Stay in the Realm (Q91264460)
• Dagens Medisin (Q11964506)
• The Norwegian Patient Registry (Q11992500)
• The Norwegian Primary Care Registry (Q91496632)
• Norwegian Surveillance System for Communicable Diseases (Q19381316)

Types

Laws & Regulations

Act of the Parliament of Norway

• act of the Parliament of Norway (Q91267389)

SELECT ?item ?itemLabel {
  # instance of (P31) subclass of (P279) Act of the Parliament of Norway (Q91267389)
  ?item wdt:P31 / wdt:P279* wd:Q91267389.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Regulation of the Government of Norway

• regulation of the government of Norway (Q4590880)

SELECT ?item ?itemLabel {
  # instance of (P31) subclass of (P279) Regulation of the Government of Norway (Q4590880)
  ?item wdt:P31 / wdt:P279* wd:Q4590880.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" "nb" }
}

Try it!

Other

• Norwegian health registry (Q91500776)

SELECT ?item ?itemLabel {
  # instance of (P31) subclass of (P279) Norwegian Health Register (Q91500776)
  ?item wdt:P31 / wdt:P279* wd:Q91500776.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Queries

Dictionaries with language Norwegian

SELECT DISTINCT ?item ?itemNativeLabel ?itemDescription ?accessStatusLabel ?website WHERE {
  ?item wdt:P31 / wdt:P279* wd:Q23622.
  ?item wdt:P407 / wdt:P279* wd:Q9043.
  OPTIONAL { ?item ( wdt:P1705| wdt:P1476 | wdt:P1448 ) ?itemNativeLabel }.
  OPTIONAL { ?item ( wdt:P856 | wdt:P953 ) ?website }.
  ## OPTIONAL { ?item wdt:P407 ?language }.
  OPTIONAL { ?item (wdt:P31 / wdt:P279*)? / wdt:P6954 ?accessStatus }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

subclass of legislative act (itemsubclass of (P279)statute (Q820655)) that applies to jurisdiction Norway (itemapplies to jurisdiction (P1001)Norway (Q20))

SELECT ?item ?itemLabel ?linkTo {
  ?item wdt:P279* wd:Q820655.
  ?item ( wdt:P1001| wdt:P17 ) wd:Q20.
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

instance of company (iteminstance of (P31)company (Q783794)) in country Norway (itemcountry (P17)Norway (Q20))

SELECT ?item ?itemLabel ?linkTo {
  ?item (wdt:P31 / wdt:P279*) wd:Q783794.
  ?item wdt:P17 wd:Q20.
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

subclass of something (?itemsubclass of (P279)type) with country Norway (?itemcountry (P17)Norway (Q20))

SELECT ?item ?itemLabel ?type ?typeLabel {
  ?item wdt:P279 ?type.
  ?item wdt:P17 wd:Q20. 
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

subclass of something (?itemsubclass of (P279)type) linked to Norway (?item?propertyNorway (Q20))

SELECT ?item ?itemLabel ?property ?propertyLabel ?type ?typeLabel {
  ?item wdt:P279 ?type.
  ?item ?prop wd:Q20.
  ?property wikibase:directClaim ?prop.
  MINUS { ?item wdt:P31 / wdt:P279* wd:Q34770 }.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Subpages

• WikiProject Norway/Aspects
• WikiProject Norway/Participants

Participants

[+] Add yourself to the list

The participants listed below can be notified using the following template in discussions:
{{Ping project|Norway}}

• Iwan.Aucamp
• Andber08
• Jon Harald Søby
• Premeditated
• Braata
• pmt
• Abbe98
• Vasmar1
• Bksm