User:Iwan.Aucamp/WIP/3GPP

From Wikidata
Jump to navigation Jump to search

Ontology[edit]

Option 1[edit]

Examples[edit]

  • 3GPP TS 29.198-04-2instance of (P31)3GPP Technical Specification link
    • 3GPP TS 29.198-04-2title (P1476)Open Service Access (OSA) Application Programming Interface (API); Part 4: Call control; Subpart 2: Generic call control Service Capability Feature (SCF)
  • 3GPP TS 29.198-04-2: Version 9.0.0instance of (P31)3GPP Technical Specification Version pdf

Option 2[edit]

Examples[edit]


  • 3GPP TR 21.905: Vocabulary for 3GPP Specificationsinstance of (P31)3GPP Technical Report link
  • 3GPP TR 21.905: Vocabulary for 3GPP Specifications: Version 15.1.0instance of (P31)3GPP Technical Report Version pdf


I think there may be some special cases which I will sort out before I create anything.

Items[edit]

Generic[edit]

Specific[edit]

Properties[edit]

Generic


Identifiers

Examples[edit]

queries[edit]

properties[edit]

SELECT ?property ?propertyLabel ?propertyDescription ?issuer ?issuerLabel {
  ?property rdf:type wikibase:Property.
  # ?properties issued by (P2378) ?issuer
  ?property wdt:P2378 ?issuer.
  # ?issuer instance of (P31) subclass of (P279) standards organization (Q1328899)
  ?issuer wdt:P31 / wdt:P279* wd:Q1328899.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100
Try it!

technical standards and standards bodies[edit]

SELECT ?item ?itemLabel ?itemDescription ?publisher ?publisherLabel ?standardsBody ?standardsBodyLabel ?instanceOf ?instanceOfLabel {
  # items instance of (P31) subclass of (P279) technical standard (Q317623)
  ?item wdt:P31 / wdt:P279* wd:Q317623.
  OPTIONAL { ?item wdt:P123 ?publisher }
  OPTIONAL { ?item wdt:P1462 ?standardsBody }
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
# GROUP BY ?item ?itemLabel ?itemDescription
LIMIT 100
Try it! 
SELECT ?item ?itemLabel ?itemDescription ?publisher ?publisherLabel ?standardsBody ?standardsBodyLabel ?instanceOf ?instanceOfLabel {
  # ?items subclass of (P279) technical standard (Q317623)
  ?item wdt:P279* wd:Q317623.
  # MINUS ?items subclass of (P279) GOST (Q1349015) - these are not english
  MINUS { ?item wdt:P279+ wd:Q1349015. }
  OPTIONAL { ?item wdt:P123 ?publisher }
  OPTIONAL { ?item wdt:P1462 ?standardsBody }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
LIMIT 100
Try it! 
SELECT ?item ?itemLabel WHERE {
  # ?items instance of (P31) subclass of (P279) standards organization (Q1328899)
  ?item wdt:P31 / wdt:P279* wd:Q1328899.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100
Try it!

editions[edit]

SELECT ?item ?itemLabel ?itemDescription {
  # items instance of (P31) subclass of (P279) version, edition, or translation (Q3331189)
  ?item wdt:P31+ / wdt:P279* wd:Q3331189.
  # items instance of (P31) subclass of (P279) technical standard (Q317623)
  ?item wdt:P31+ / wdt:P279* wd:Q317623.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
# GROUP BY ?item ?itemLabel ?itemDescription
LIMIT 100
Try it! 
SELECT ?item ?itemLabel ?itemDescription {
  # ?items edition or translation of (P629) ?work
  ?item wdt:P629 ?work.
  # ?work instance of (P31) subclass of (P279) technical standard (Q317623)
  ?work wdt:P31+ / wdt:P279* wd:Q317623.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
# GROUP BY ?item ?itemLabel ?itemDescription
LIMIT 100
Try it! 
SELECT ?item ?itemLabel ?itemDescription ?edition ?editionLabel {
  # ?items has edition (P747) ?edition
  ?item wdt:P747 ?edition.
  # items instance of (P31) subclass of (P279) technical standard (Q317623)
  ?item wdt:P31+ / wdt:P279* wd:Q317623.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
# GROUP BY ?item ?itemLabel ?itemDescription
LIMIT 100
Try it!

3GPP[edit]

SELECT ?item ?itemLabel ?itemDescription ?instanceOf ?instanceOfLabel {
  # items with publisher (P123) or standards body (P1462) being 3GPP (Q229804)
  ?item (wdt:P123+|wdt:P1462+) wd:Q229804.
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
} LIMIT 100
Try it!

ETSI[edit]

SELECT ?item ?itemLabel ?itemDescription ?instanceOf ?instanceOfLabel {
  # items with publisher (P123) or standards body (P1462) being ETSI (Q899383)
  ?item wdt:P31? / wdt:P279* / (wdt:P123+|wdt:P1462+) wd:Q899383.
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
Try it! 
SELECT ?item ?itemLabel ?itemDescription ?instanceOf ?instanceOfLabel {
  # items with publisher (P123) or standards body (P1462) being ETSI (Q899383)
  ?item (wdt:P123+|wdt:P1462+) wd:Q899383.
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
} LIMIT 100
Try it! 
SELECT ?item ?itemLabel ?itemDescription ?instanceOf ?instanceOfLabel {
  # items instance of (P31) subclass of (P279) ETSI Standard (Q51885719)
  ?item wdt:P31+ / wdt:P279* wd:Q51885719.
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
} LIMIT 100
Try it! 
SELECT ?item ?itemLabel ?itemDescription ?instanceOf ?instanceOfLabel {
  # items with publisher (P123) or standards body (P1462) being ETSI (Q899383)
  ?item wdt:P31? / wdt:P279* / (wdt:P123+|wdt:P1462+) wd:Q899383.
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
Try it!

ITU[edit]

SELECT ?item ?itemLabel ?itemDescription ?publisherLabel ?standardsBodyLabel ?instanceOfLabel {
  # items with publisher (P123) or standards body (P1462) being ITU (Q376150)
  { ?item (wdt:P123+|wdt:P1462+) wd:Q376150. }
  UNION
  # items with publisher (P123) or standards body (P1462) being ITU-T (Q4007363)
  { ?item (wdt:P123+|wdt:P1462+) wd:Q4007363. }
  UNION
  # items with publisher (P123) or standards body (P1462) being ITU-R (Q376047)
  { ?item (wdt:P123+|wdt:P1462+) wd:Q376047. }
  OPTIONAL { ?item wdt:P123 ?publisher }
  OPTIONAL { ?item wdt:P1462 ?standardsBody }
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
Try it! 
SELECT ?item ?itemLabel ?itemDescription ?instanceOf ?instanceOfLabel {
  # items instance of (P31) subclass of (P279) ETSI Standard (Q51885719)
  ?item wdt:P31+ / wdt:P279* wd:Q51885719.
  OPTIONAL { ?item wdt:P31 ?instanceOf }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
} LIMIT 100
Try it!

links[edit]

URIs[edit]

Specific assignments:

Incoming[edit]

Trees[edit]

  • subclass of (P279)report (Q10870555)
    • Wikidata generic tree
    • Wikidata Graph Builder
    • PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?linkTo {
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q10870555 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 3 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
      Try it! 
    • SELECT ?item ?itemLabel ?linkTo {
  ?item wdt:P279 wd:Q10870555
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
      Try it!
  • subclass of (P279)technical standard (Q317623)
    • Wikidata generic tree
    • Wikidata Graph Builder
    • PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?linkTo {
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q317623 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 3 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
      Try it! 
    • SELECT ?item ?itemLabel ?linkTo {
  ?item wdt:P279 wd:Q317623
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
      Try it!
  • subclass of (P279)specification (Q2101564)
    • Wikidata generic tree
    • Wikidata Graph Builder
    • PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?linkTo {
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q2101564 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 3 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
      Try it! 
    • SELECT ?item ?itemLabel ?linkTo {
  ?item wdt:P279 wd:Q2101564
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}
      Try it!
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Iwan.Aucamp/WIP/3GPP&oldid=1169478440"